توابع پایه اکسل - تابع OR

تابع OR تابع منطقی است که برای بررسی چند شرط به طور همزمان استفاده می‌شود. OR در صورتی TRUE را بر می‌گرداند که حداقل یکی از شرط‌ها برقرار باشد. اگر همه شروط برقرار نباشد ، تابع FALSE را بر می‌گرداند. تابع OR اغلب با تابع IF استفاده می‌شود و می‌تواند با NOT و AND برای بررسی شرط‌های منطقی ترکیب شود.

هدف تابع

چندین شرط به طور همزمان ایجاد کنید.

خروجی تابع

TRUE یا FALSE 

ترکیب تابع

= OR ( logical1 , [logical2] , ... )

ورودی تابع (مولفه‌ها‌)

logical1 – اولین شرط یا مقدار منطقی برای ارزیابی.
logical2 – [اختیاری] شرط دوم یا مقدار منطقی برای ارزیابی.

نحوه استفاده از تابع

تابع OR یکی از توابع منطقی اکسل است که طراحی شده تا چندین شرط را به طور همزمان ایجاد و بررسی کند. در صورتی که حداقل یک شرط برقرار باشد ، TRUE را بر می‌گرداند و اگر همه شروط برقرار نباشد FALSE را بر می‌گرداند.

تابع OR اغلب با توابع دیگری مانند AND، NOT و IF ترکیب می‌شود تا بررسی‌های منطقی پیچیده‌تری بسازد. معمولا در مولفه اول تابع IF و در فرمول‌های قالب‌بندی شرطی و اعتبارسنجی داده‌ها ظاهر می‌شود. تابع OR راه حلی مناسب برای ساده کردن فرمول‌های پیچیده شامل تعداد زیادی از IF های تودرتو است.

مبانی تابع OR

هدف تابع OR ارزیابی همزمان بیش از یک شرط و بازگرداندن TRUE در صورت صحیح بودن حداقل یک شرط است. تابع OR می‌تواند تا 255 شرط جداگانه را کنترل کند که به عنوان مولفه‌هایی با عناوینی مانند "logical2" ، "logical1" و "logical3" و … وارد می‌شوند. هر "logical" شرطی است که می‌تواند به عنوان TRUE یا FALSE ارزیابی ‌شود. مولفه‌های ارائه شده به تابع OR می‌تواند ثابت‌ها، آدرس سلول‌ها یا عبارات منطقی باشند.

 OR در صورتی TRUE را بر می‌گرداند که حداقل نتیجه یک شرط TRUE باشد: 

= OR ( FALSE , FALSE , TRUE )   //   بازگردانده می‌شود TRUE

چنانچه نتیجه همه شرط‌ها FALSE باشد، بلافاصله FALSE را بر می‌گرداند:

= OR ( FALSE , FALSE, FALSE )   //   بازگردانده می‌شود FALSE

به طور معمول، عبارات منطقی به عنوان مولفه به OR ارائه می‌شوند، به عنوان مثال:

= OR ( A1 > 0 , A1 < 5 )
= OR ( A1 > 0 , B1 > 0 )
= OR ( A1 = "قرمز" , B1 = "کوچک" )

 تمام مولفه‌های فرمول‌های بالا به عنوان TRUE یا FALSE ارزیابی می‌شوند. توجه داشته باشید که مقادیر متنی که در مقایسه‌ها استفاده می‌شود باید داخل دو گیومه ("") محصور شوند. 

تابع OR همچنین اعداد را به عنوان TRUE یا FALSE ارزیابی می‌کند و هر عددی به جز صفر (0) را TRUE در نظر می‌گیرد. می‌توانید این رفتار را در فرمول‌های زیر مشاهده کنید:

= OR ( 0 , 0 , 3 )   //   بازگردانده می‌شود TRUE
= OR ( 0 , 0 , 0 )   //   بازگردانده می‌شود FALSE

مثال – مقدار x یا y یا z است

می توانید از OR برای بررسی یکی از چند مقدار عددی استفاده کنید. به عنوان مثال ، در برگه زیر، از تابع OR برای بررسی اینکه آیا کدهای ستون B برابر 115 ، 120 یا 125 است ، استفاده می‌کنیم. فرمول سلول D3 به این صورت است:

= OR ( B3 = 115 , B3 = 120 , B3 = 125 )

توجه داشته باشید که در حال بررسی مقادیر عددی هستیم بنابراین اعداد به صورت خام و بدون نویسه نقل قول ("") ظاهر می‌شوند.

مثال - ترکیب OR با تابع IF

تابع OR اغلب داخل تابع IF به عنوان مولفه اول ترکیب می‌شود تا فرمول پیچیده‌‌ای را ساده کند. به عنوان مثال ، در برگه زیر، هدف بررسی امتیازات ستون‌های B و C است. اگر هر یک از امتیازها زیر 750 باشد، نتیجه باید "مردود" باشد. اگر هر دو امتیاز 750 یا بالاتر باشد، نتیجه باید "تأیید" باشد. فرمول سلول E3 این است:

= IF ( OR ( B3 < 750 , C3 < 750 ) , "مردود" , "تائید" )

همانطور که فرمول در سلول‌های زیرین کپی می شود، برای هر ردیف از داده ها "تأیید" یا "مردود" را بر می‌گرداند.

مثال - اگر این یا آن

برگه زیر نمونه‌ای از مثال بالا است. این بار، هدف این است ردیف‌هایی را که رنگ آنها "قرمز" یا  سایز آنها "S" است، علامت گذاری کنیم. فرمول سلول E3 این است:

= IF ( OR ( B3 = "قرمز" , C3 = "S" ) , "x" , "" )

می‌توانید "x" را با هر مقدار دیگری جایگزین کنید. 

مثال - ترکیب OR با AND

برای انجام بررسی‌های پیشرفته ‌تر می‌توانید تابع OR را با تابع AND ترکیب کنید. در برگه زیر، هدف شناسایی رکوردهایی است که رنگ آن "قرمز" یا "سبز" و مقدار آن بیش از 100 است. مولفه اول تابع IF با AND و OR ایجاد می شود:

AND ( OR ( B3 = "قرمز" , B3 = "سبز" ) , C3 > 100 )

فرمول کامل سلول E3 به این صورت است:

= IF ( AND ( OR ( B3 = "قرمز" , B3 = "سبز" ) , C3 > 100 )  ,"x" , "" )

توجه داشته باشید که مقادیر متنی "قرمز" و "سبز" در دو گیومه ("") قرار می‌گیرند اما عدد 100 اینطور نیست.

مثال - OR با قالب بندی شرطی

تابع OR اغلب در قوانینی که قالب بندی شرطی را راه اندازی می‌کنند استفاده می‌شود. در برگه زیر ، از قالب‌بندی شرطی برای مشخص کردن ردیف‌هایی استفاده می‌کنیم که رنگ آن قرمز یا سبز و مقدار آن بیش از 100 است. قالب‌بندی شرطی در محدوده B3:C12 اعمال می‌شود و فرمول اجرای قالب‌بندی به این صورت است:

= AND ( OR ( $ B3 = "قرمز" , $ B3 = "سبز" ) , $ C3 > 100 )

توجه داشته باشید که B3 $ و  C3 $ آدرس‌های ترکیبی با ستون ثابت هستند تا کل ردیف‌ها را شامل شود.

توجه داشته باشید که تابع IF مورد نیاز نیست. از آنجایی که  TRUE  ،  AND  یا FALSE را بر می‌گرداند، برای قالب بندی شرطی کافی است.

مثال - OR و محدوده

امکان استفاده از OR با طیف وسیعی از مقادیر وجود دارد. در برگه زیر، فرمول موجود در سلول J3 به صورت زیر است:

= IF ( OR ( C3:H3 > 65 ) , " مردود " , " قبول " )

توجه: این فرمول ، آرایه‌ای است و باید با کلیدهای Control + Shift + Enter در نسخه‌های اکسل 2019 و قبل از آن وارد شود. در اکسل 2021 یا نسخه‌های جدیدتر ، تنها فشردن کلید Enter کافی است.

در مثال فوق ، تابع OR داخل تابع IF به عنوان مولفه اول استفاده می‌شود. این فرمول در صورتی که نمره یکی از هر شش درس کوپکتر از 65 باشد، "مردود" را بر می‌گرداند. در غیر این صورت ، نتیجه "قبول" است. 

نکته: همانطور که در بالا مشاهده شد، تابع OR نتایج را در یک نتیجه جمع می‌کند. این بدان معنی است که نمی‌توان از آن در عملیات آرایه‌ای که باید آرایه‌ای از نتایج را ارائه دهد استفاده کرد. برای رفع این محدودیت، می‌توانید از منطق بولی استفاده کنید. 

یادداشت 

•  تابع OR می‌تواند تا 255 شرط را مدیریت کند.
•  هر شرط منطقی باید TRUE یا FALSE ارزیابی شود. 
• تابع OR به حروف بزرگ و کوچک لاتین حساس نیست.
• تابع OR از نویسه‌های خاص پشتیبانی نمی‌کند.
• مقادیر متنی یا سلول‌های خالی ارائه شده به عنوان مولفه ، نادیده گرفته می‌شود.
• اگر هیچ مقدار منطقی در طول ارزیابی پیدا نشود یا ایجاد نشود، تابع OR  خطای VALUE# را بر می‌گرداند.

لطفا دیدگاه خود را در کادر پایین با ما به اشتراک بگذارید.

آیا می‌خواهید:

• برنامه‌های قدرتمند و انعطاف پذیر با اکسل ایجاد کنید.
• فرصت های شغلی جدید کسب کنید.

کتاب‌های معرفی شده ، راهنمای گام به گام جامع و عملی برای افرادی است که (مانند شما) می‌خواهند به این اهداف برسند.