تابع COUNTIFS تعداد سلولهایی که با یک یا چند معیار و شرط مطابقت دارند را بر میگرداند. هر شرط با یک محدوده و معیار جداگانه ارائه میشود و برای اینکه یک سلول در شمارش قرار گیرد، باید همه شرایط درست (TRUE) باشد. COUNTIFS میتواند برای شمارش سلولهایی که حاوی تاریخ، اعداد و متن هستند استفاده شود.
هدف تابع
شمارش سلولهای یک محدوده که با چندین شرط تعریف شده مطابقت دارند.
خروجی تابع
عددی که نشاندهنده سلولهای شمارش شده است.
ترکیب عمومی تابع
= COUNTIFS (range1 , criteria1 , [range2] , [criteria2] ,... )
ورودی تابع (مولفهها)
Range1 – اولین محدودهای برای ارزیابی
Criteria1 – معیارهایی که باید در محدوده مشخص شده در مولفه Range1 استفاده شوند.
Range2 – [اختیاری] محدوده دوم برای ارزیابی
Criteria2 – [اختیاری] معیارهایی که باید روی محدوده مشخص شده در مولفه Range2 استفاده شوند.
نحوه استفاده از تابع
تابع COUNTIFS سلولهای یک محدوده را در صورت برآورده شدن یک یا چند شرط ، شمارش میکند. این تابع یکی از پرکاربردترین توابع اکسل است و آن را در فایلهای اکسلی که شمارشهای شرطی را بر اساس تاریخ، متن یا اعداد محاسبه میکنند، خواهید یافت. COUNTIFS طراحی منحصر به فردی دارد که شرطهای منطقی را به دو بخش تقسیم میکند. در نتیجه، نحوه تعریف شرطها در COUNTIFS میتواند کمی پیچیده باشد و عادت کردن به آن کمی طول میکشد. به خاطر داشته باشید که COUNTIFS از "منطق تابع AND" استفاده میکند - برای اینکه سلولی در شمارش نهایی گنجانده شود، همه شرطها باید درست (TRUE) باشند.
ویژگیهای کلیدی
- تعداد سلولهایی که یک یا چند شرط را برآورده میکنند، میشمارد.
- هر شرط جدید نیاز به یک محدوده و معیار جدید دارد.
- با تاریخ، متن و اعداد کار میکند.
- برای اینکه سلولی در شمارش نهایی لحاظ شود، همه معیارها باید درست باشند.
- اگر محدودهها اندازه یکسانی نداشته باشند، خطای ! VALUE# را بر میگرداند.
- از اکسل ۲۰۰۷ به بعد در همه نسخههای اکسل موجود است.
برخلاف اکثر توابع اکسل ، تابع COUNTIFS برای مولفه range به یک محدوده واقعی نیاز دارد. اگر سعی کنید از آرایه استفاده کنید، اکسل اجازه ورود فرمول را نمیدهد.
ترکیب تابع
تابع COUNTIFS تعداد سلولهای یک محدوده که یک یا چند شرط را برآورده میکنند، میشمارد. ترکیب مولفههای آن به تعداد شرطهای مورد ارزیابی بستگی دارد. هر شرط به صورت یک جفت مولفه محدوده / معیار ارائه میشود:
= COUNTIFS ( range , criteria ) // تابع با یک شرط
= COUNTIFS ( range , criteria , range ,criteria ) // تابع با دو شرط
اگر دو شرط وجود داشته باشد، دو جفت محدوده/معیار وجود خواهد داشت. اگر سه شرط وجود داشته باشد، سه جفت محدوده/معیار وجود خواهد داشت و به همین ترتیب.
همه محدودهها باید اندازه یکسانی داشته باشند. چنانچه اندازه محدودههای معرفی شده یکسان نباشد، COUNTIFS خطای ! VALUE# را بر میگرداند!
مثال پایه
برگه زیر مقدار فروش هر استان شامل دادههای تاریخ ، رنگ و تعداد است. از COUNTIFS برای انجام محاسبات زیر استفاده میکنیم:
(1) شمارش سفارشهایی که رنگ آنها قرمز است
(2) شمارش سفارشهایی که رنگ آنها قرمز و مربوط به تهران هستند
(3) شمارش سفارشهایی که رنگ آنها قرمز و فروششان بالای 80 واحد است
(4) شمارش سفارشهای قرمز رنگ مربوط به تهران که فروش آنها بالای 80 واحد است.
فرمولهای درج شده در سلولهای محدوده I3:I6 به این شکل هستند:
= COUNTIFS ( C3:C13 , "قرمز" )
= COUNTIFS ( C3:C13 , "قرمز" , D3:D13 , "تهران" )
= COUNTIFS ( C3:C13 , "قرمز" , F3:F13 , ">80" )
= COUNTIFS ( C3:C13 , "قرمز" , F3:F13 , ">80" , D3:D13 , "تهران" )
ترجمه فرمول سلول I6 این است: سطرهایی را بشمار که رنگ آنها "قرمز" ، فروش آنها بیشتر از 80 واحد و استان آنها "تهران" است. نتیجه 2 است زیرا دو سطر وجود دارد که رنگ آنها قرمز، مقدار آنها بزرگتر از 80 و استان آنها تهران است. هر شرط به یک جفت محدوده/معیار جداگانه نیاز دارد و در مجموع سه جفت وجود دارد.
چند نکته قابل توجه در رابطه با فرمولهای بالا وجود دارد:
- هر شرط به یک جفت محدوده/معیار جداگانه نیاز دارد.
- همه مولفههای range باید اندازه یکسانی داشته باشند.
- ترتیب نمایش شرطها مهم نیست.
- معیارها میتوانند در صورت نیاز شامل عملگرهای منطقی (>،<،<>،<=،>=) باشند.
- علامت تساوی (=) برای معیارهای "برابر است با" لازم نیست (یعنی از "قرمز" به جای "=قرمز" استفاده کنید).
- COUNTIFS به حروف کوچک و بزرگ لاتین حساس نیست، بنابراین "red" و "Red" نتایج یکسانی را بر میگرداند.
- اعداد هنگام استفاده با عملگرها (مثلا ">80") باید داخل علامت نقل قول (") قرار گیرند.
- COUNTIFS از منطق " تابع AND " استفاده میکند و همه شروط باید درست باشد.
نحوه معرفی مولفه criteria در COUNTIF تا حدودی غیرمعمول است. به جای اینکه به سادگی ">80" را به عنوان معیار وارد کنید ، باید آن را داخل علامت نقل قول دوتایی وارد کنید (">80"). اگر مقادیر را طبق دستورالعمل وارد نکنید، اکسل اجازه ورود فرمول را نمیدهد.
اعمال معیارها
تابع COUNTIFS از عملگرهای منطقی (>،<،<>،=) و نویسههای جایگزین (*،?) برای مطابقت پشتیبانی میکند. بخش چالش برانگیز استفاده از تابع COUNTIFS شکل ترکیب مورد نیاز برای اعمال معیارها است. دلیل این امر این است که COUNTIFS جز هشت تابعی است که بررسی شروط را با دو مولفه range و criteria انجام میدهند. به دلیل این طراحی، عملگرها باید در داخل نقل قولهای دوتایی ("") قرار گیرند.
جدول زیر نمونههایی از شکل ترکیب معیارهای رایج را نشان میدهد:
توجه داشته باشید که دو مثال آخر شامل نویسه الحاق (&) هستند. وقتی مولفه criteria شامل مقداری از سلول دیگر یا نتیجه یک فرمول است، عملگرهای منطقی مانند "<" باید با نویسه الحاق (&) به هم متصل شوند. دلیل این امر آن است که اکسل قبل از اینکه بتواند از یک عملگر استفاده کند، ابتدا باید مقدار آدرسهای سلول و فرمولها را بدست آورد.
معیارهای موجود در سلول دیگر
روش مناسب استفاده از COUNTIFS این است که معیارها را در سلول دیگری قرار دهید و سپس در فرمول خود به آن سلول ارجاع دهید. این کار تغییر معیارها را در صورت نیاز بدون ویرایش فرمول اصلی آسان میکند. به عنوان مثال ، میتوانید سلولهای محدودهای را که مقادیر آنها برابر با مقدار سلول A1 هستند را به صورت زیر شمارش کنید:
= COUNTIFS ( range , A1 )
وقتی شرطی به عملگر نیاز دارد ، باید آدرس سلول را به عملگر الحاق کنید. برای مثال ، برای شمارش سلولهای یک محدوده که مقدار آنها بزرگتر از مقدار سلول A1 هستند، از فرمولی به صورت زیر استفاده کنید:
= COUNTIFS ( range , ">" & A1 )
توجه داشته باشید که عملگر "<" را با نویسه الحاق (&) به سلول A1 متصل میکنیم. در برگه زیر ، تابع COUNTIFS طوری پیکربندی شده است که شمارش تمام فروشهای بیشتر از مقدار موجود در G2 را برگرداند. توجه داشته باشید که عملگر (<) که متن است، باید داخل علامت نقل قول قرار گیرد. فرمول سلول G3 به صورت زیر وارد شده است:
= COUNTIFS ( D3:D13 , ">" & G2 ) // است G2شمارش سلولهایی که مقدارشان بزرگتر از مقدار سلول
آدرسهای سلول را داخل علامت نقل قول به صورت "A1" قرار ندهید. انجام این کار آنها را به متن تبدیل میکند.
مساوی نیست با
برای بیان معیارهای «مساوی نیست با»، از عملگر « <> » که داخل نماد نقل قول ("") قرار گرفته است، استفاده کنید. برای مثال، همانطور که در فرمولهای زیر مشاهده میکنید، از « قرمز <> » برای رنگهای که قرمز نیست و از « آبی <> » برای رنگهای که آبی نیست استفاده کنید:
= COUNTIFS ( B3:B7 , "<>قرمز ") // شمارش رنگهایی که "قرمز" نیست
= COUNTIFS ( B3:B7 , "<>آبی") // شمارش رنگهایی که "آبی" نیست
= COUNTIFS ( B3:B7 , "<>" & E5) // برابر نیست E5شمارش سلولهایی که مقدار آنها با سلول
به موارد زیر توجه کنید:
- در فرمول آخر، مستقیما از E5 استفاده میکنیم، بنابراین باید معیار را به صورت E5 &"<>" وارد کنیم.
- از نماد نقل قول در اطراف آدرس سلول استفاده نکنید.
سلولهای خالی
تابع COUNTIFS میتواند سلولهایی که خالی هستند یا حاوی مقداری باشند را بشمارد. از یک رشته خالی ("") برای هدف قرار دادن سلولهای خالی و از عملگر "نامساوی با" ("<>") برای هدف قرار دادن سلولهایی که خالی نیستند، استفاده کنید. در برگه زیر COUNTIFS برای شمارش سلولهای خالی و غیر خالی بسته به اینکه ستون D حاوی "x" باشد یا خالی باشد، استفاده میشود:
= COUNTIFS ( D3:D7 , "") // شمارش سلولهای خالی
= COUNTIFS ( D3:D7 , "<>") // شمارش سلولهایی که خالی نیستند
در فرمول دوم، تابع COUNTIFS شمارش سلولهایی که خالی نیست و حاوی هر مقداری میتواند باشد را بدون توجه به مقادیر آنها باز میگرداند. نتیجه این است که ۲ فاکتور «پرداخت نشده» (خالی) و ۳ فاکتور پرداخت شده وجود دارد. برای دقیقتر کردن محاسبه ، میتوانید از فرمولی به صورت زیر استفاده کنید که تنها سلولهایی را شمارش کند که حاوی "x" باشد:
= COUNTIFS ( D3:D7 , "x") // است"x"شمارش سلولهایی که شامل
تاریخها
در اکسل، تاریخها اعداد سریالی هستند، بنابراین میتوانید از آنها با عملگرهایی مانند <,>، <=، >= مانند هر عدد دیگری استفاده کنید. بخش چالش برانگیز استفاده از تاریخها در شرطهای COUNTIFS وارد کردن تاریخ به روشی است که اکسل آن را بفهمد. سادهترین روش برای انجام این کار، ارجاع به یک تاریخ معتبر در سلول دیگر است. به عنوان مثال ، میتوانید با استفاده از فرمول زیر تاریخهایی که بزرگتر از تاریخ درج شده در سلول A1 هستند را بشمارید:
= COUNTIFS ( range , ">" & A1 ) // A1 شمارش تاریخهای بزرگتر از
اگر میخواهید تاریخ را به صورت " هارد کد" در تابع COUNTIFS وارد کنید، بهترین راه استفاده از تابع DATE است. برای مثال، برای شمارش تاریخهای بزرگتر از ۱-ژانویه-۲۰۲۴، میتوانید از COUNTIFS به این صورت استفاده کنید:
= COUNTIFS ( range , ">" & DATE ( 2024 , 1 , 1 ) // شمارش تاریخهای بزرگتر از ۱ ژانویه ۲۰۲۴
برگه زیر از هر دو روش استفاده میکند:
فرمولهای موجود در F3:F6 به شرح زیر هستند:
= COUNTIFS ( B3:B10 , "<" & DATE ( 2025 , 3 , 1 ) )
= COUNTIFS (B3:B10 , ">=" & DATE ( 2025 , 3 , 31 ) )
= COUNTIFS (B3:B10 , ">" & E8 )
= COUNTIFS (B3:B10 , ">=" & DATE ( 2025 , 5 ,1 ) , B3:B10 , "<=" & DATE ( 2025 , 5 , 31 ) )
به موارد زیر توجه کنید:
- هنگام استفاده از یک تابع با یک عملگر، باید مانند (2024,3,1) DATE &"<" عمل الصاق کردن را انجام دهید.
- تابع DATE تضمین میکند که اکسل تاریخ را به درستی تفسیر کند.
- ارجاع به یک تاریخ در سلول دیگر، تغییر تاریخ را بدون ویرایش فرمول آسان میکند.
نکته حرفهای: از درج تاریخ در فرمول خودداری کنید. به جای آن ، تاریخ را در یک سلول دیگر قرار دهید، سپس در فرمول خود به آن سلول ارجاع دهید. با انجام این کار میتوانید به راحتی تاریخ مورد استفاده را ببینید و در صورت نیاز بدون ویرایش فرمول ، آن را تغییر دهید.
نویسههای جایگزین
تابع COUNTIFS از سه نویسه جایگزین پشتیبانی میکند که میتوانید در معرفی معیارها برای مطابقت بیشتر از آنها استفاده کنید:
نماد ستاره (*) - با صفر یا چند نویسه مطابقت دارد
نماد سوال (?) - با هر نویسهای مطابقت دارد
نماد مد (~) – برای ارزیابی خود نویسههای جایگزین استفاده میشود
برای شمارش سلولهایی که حاوی ۳ نویسه متنی هستند، میتوانید از فرمول زیر استفاده کنید:
= COUNTIFS ( range , "???" ) // سلولهایی که شامل ۳ حرف باشند
توجه داشته باشید که نویسههای جایگزین تنها با مقادیر متنی کار میکنند. فرمول بالا اعداد سه رقمی مانند ۱۲۳ یا ۸۱۲ را شمارش نمیکند.
برگه زیر نحوه استفاده از نویسههای جایگزین را با تابع COUNTIFS نشان میدهد. فرمولهای F3:F6 معیارهای شرح داده شده در ستون E را اعمال میکنند.
= COUNTIFS ( B3:B13 , " *ان") // استانهایی که به “ ان” ختم میشود
= COUNTIFS ( B3:B13 , "*ی") // استانهایی که به “ ی” ختم میشود
= COUNTIFS ( B3:B13 , "?????") // استانهایی که “5 حرفی” هستند
= COUNTIFS ( B3:B13 , "*~*") // استانهایی که به “ * ” ختم میشود
توجه داشته باشید که فرمول سلول F6 از "*~*" برای مطابقت با نماد ستاره (*) که در انتهای "تهران*" در سلول C7 قرار دارد، استفاده میکند. نماد مد (~) امکان میدهد خود نویسه جایگزین را پیدا کنید. برای مطابقت با نماد سوال (?)، از "?~"؛ برای تطبیق نماد ستاره (*)، از "*~"؛ و برای تطبیق نماد مد (~)، از "~~" استفاده کنید.
جدول زیر مثالهای بیشتری از نحوه استفاده از نویسههای جایگزین را نشان میدهد:
نکته: نویسههای جایگزین فقط با متن کار میکنند، نه با اعداد.
منطق تابع OR
تابع COUNTIFS برای اعمال چند شرط با منطق تابع AND طراحی شده است، بنابراین روش مشخصی برای شمارش سلولها با منطق تابع OR "این یا آن" وجود ندارد. یک راه حل این است که معیارها را به عنوان یک آرایه ثابت مانند {"قرمز","آبی"} ارائه داده و سپس فرمول COUNTIFS را درون تابع SUM به صورت تو در تو قرار دهید:
= SUM ( COUNTIFS ( range , {"قرمز","آبی"} )) // شمارش قرمز یا آبی
فرمول فوق سلولهای موجود در مولفه range را زمانی شمارش میکند که شامل "قرمز" یا "آبی" باشند. در واقع COUNTIFS دو تعداد را در یک آرایه بر میگرداند (یکی برای "قرمز" و دیگری برای "آبی") و تابع SUM مجموع این دو تعداد را بر میگرداند.
جدول خلاصه
میتوانید از COUNTIFS برای ایجاد یک جدول خلاصه ساده استفاده کنید. در برگه زیر، لیستی از رنگهای غیرتکراری در محدوده F3:F7 داریم. هدف شمارش مقادیر ستون C بر اساس رنگ است. فرمول سلول G3، که در سلولهای پایینی هم کپی شده است ، به صورت زیر است:
= COUNTIFS ( $C$3:$C$14 , F3 )
توجه داشته باشید که مولفه اول به صورت آدرس مطلق قفل شده است تا از تغییر آدرس سلولهای فرمول هنگام کپی فرمول جلوگیری شود. اگر از اکسل نسخه ۲۰۲۱ یا بالاتر استفاده میکنید، میتوانید مقادیر ستون جدول خلاصه را به طور همزمان با یک فرمول آرایه پویا به صورت زیر در سلول G3 محاسبه کنید:
= COUNTIFS ( C3:C14 , F3:F7)
در این حالت به آدرسدهی مطلق نیازی نداریم زیرا یک فرمول واحد همه نتایج را ایجاد میکند. میتوانید با استفاده از تابع UNIQUE در سلول F3 یک قدم جلوتر بروید تا لیستی از رنگهای غیر تکراری به صورت محدوده آبشاری ایجاد کنید، سپس مستقیما به این محدوده آبشاری به صورت زیر ارجاع دهید:
= COUNTIFS ( C3:C14 , F3 # )
مزیت استفاده از محدوده آبشاری این است که چنانچه لیست رنگها تغییر کند، تعداد آنها بهروزرسانی میشود.
در اکسل ۳۶۵، میتوانید از تابع جدید GROUPBY نیز برای ایجاد جدول خلاصه استفاده کنید.
مشکل کار با آرایهها
یکی از محدودیتهای مهم COUNTIFS این است که اجازه استفاده از آرایه در مولفه اول را نمیدهد. یعنی نمیتوانید آرایهای را از تابع دیگر به COUNTIFS به عنوان محدوده معرفی کنید. برای درک مشکل، به برگه زیر توجه کنید که در آن 10 تاریخ در ستون B و 10 مقدار در ستون C داریم. هدف ایجاد فرمولی برای شمارش بر اساس سال است. میتوانیم این کار را با فرمول زیر انجام دهیم:
= COUNTIFS ( B3:B12 , ">=" & DATE ( E3 , 1 , 1 ) , B3:B12 , "<=" & DATE ( E3 , 12 ,31 ) )
نکته: معمولا در فرمولها از آدرسدهی مطلق استفاده میکنم تا فرمول بدون تغییر کپی شود، اما در اینجا آدرسها را نسبی گذاشتهام تا خواندن و درک فرمول آسانتر شود.
این فرمول به خوبی کار میکند، اما کمی پیچیده است. اگر با فرمولهای اکسل کمی آشنایی دارید، ممکن است فکر کنید که میتوانید از ترکیب COUNTIFS و YEAR در یک فرمول به صورت زیر استفاده کنید:
= COUNTIFS ( YEAR ( B3:B12 ) , E3 )
ایده این است که سال را از تاریخهای ستون B با استفاده از تابع YEAR استخراج و سپس از عدد ۲۰۲۴ در سلول E5 به عنوان معیار استفاده کنید. اگر این روش جواب میداد، خیلی خوب میشد. اما اکسل حتی اجازه نمیدهد این فرمول را وارد کنید. اگر امتحان کنید، با خطای عمومی «مشکلی در فرمول وجود دارد» مواجه خواهید شد.
مشکل این است که COUNTIFS برای مولفه range به یک محدودهی مناسب نیاز دارد، اما YEAR(B3:B12) آرایهای مانند آرایه زیر را بر میگرداند:
{2025;2025;2025;2025;2025;2024;2024;2024;2024;2024}
برای روشن شدن موضوع ذکر کنم که ، استفاده از تابع YEAR به این شکل در اکثر فرمولهای دیگر به خوبی کار میکند. با این حال COUNTIFS برای مدیریت آرایهها برنامهریزی نشده است، بنابراین کار نخواهد کرد.
چگونه میتوانیم این مشکل را حل کنیم؟
فرمول جایگزین خوب این است که از تابع SUMPRODUCT به صورت زیر استفاده کنید:
= SUMPRODUCT ( - - ( range = criteria ) )
اگر این الگو را با مثال ارائه شده تطبیق دهیم، به نتیجه زیر میرسیم:
= SUMPRODUCT ( - - ( YEAR ( B3:B12 ) = E3 ) )
این فرمول کمی سادهتر از فرمول COUNTIFS ارائه شده است و مثال خوبی از این است که چگونه SUMPRODUCT میتواند یک مسئله پیچیده را در یک فرمول حل کند.
به خاطر داشته باشید: اگر سعی کنید یک محدوده آرایهای برای مولفه اول تابع COUNTIFS ارائه دهید، نمیتوانید فرمول را وارد کنید زیرا اکسل پنجره خطای "مشکلی در فرمول وجود دارد" را نمایش میدهد که "مشکل آرایه" به صراحت ذکر نشده است.
محدودیتها
تابع COUNTIFS چند محدودیت دارد که باید از آنها آگاه باشید:
- COUNTIFS به حروف کوچک و بزرگ لاتین حساس نیست. از تابع EXACT برای شمارشهای حساس به حروف بزرگ و کوچک لاتین استفاده کنید.
- COUNTIFS به یک محدوده واقعی برای مولفه اول خود نیاز دارد. نمیتوانید یک محدوده آرایهای ارائه دهید. این بدان معناست که نمیتوانید مقادیر محدوده داخل فرمول را قبل از اعمال معیارها تغییر دهید.
- COUNTIFS اعداد طولانی بزرگتر از ۱۵ رقم را به درستی نمیشمارد.
- اگر با استفاده از تابع COUNTIFS به محدودهای در فایل اکسل دیگری ارجاع دهید، برای محاسبه نتیجه نیاز است که فایل اکسل باز باشد، در غیر این صورت COUNTIFS خطای !VALUE# را بر میگرداند. برای حل این مشکل، میتوانید از تابع SUMPRODUCT استفاده کنید که این محدودیت را ندارد.
رایجترین روش برای دور زدن اکثر این محدودیتها، استفاده از تابع SUMPRODUCT است. با این حال، آخرین نسخه اکسل جایگزینهای قدرتمندی از جمله BYROW، BYCOL و GROUPBY ارائه میدهد.
نکات
- تمام محدودهها باید اندازه یکسانی داشته باشند، در غیر این صورت COUNTIFS خطای !VALUE# را بر میگرداند.
- رشتههای متنی (غیر عددی) در معیارها باید داخل علامت نقل قول قرار گیرند (مثلاً "<100"، ">32"، "قرمز")
- آدرسهای سلول استفاده شده در مولفه دوم داخل علامت نقل قول قرار نمیگیرند، مثلاً "<"&A1
- نویسههای جایگزین را میتوان در معیارها استفاده کرد.
- COUNTIFS میتواند تا 127 شرط را مدیریت کند.
- COUNTIFS به یک محدوده معمولی نیاز دارد و نمیتوانید از محدوده به صورت آرایه استفاده کنید.
- COUNTIFS هنگام ارزیابی برای مطابقت با رشتههای طولانیتر از 255 نویسه، نتایج نادرستی را بر میگرداند.
- COUNTIFS هنگام ارجاع به یک فایل اکسل دیگر که باز نیست، خطای !VALUE# را بر میگرداند.
لطفا دیدگاه خود را در کادر پایین با ما به اشتراک بگذارید.
آیا میخواهید:
- برنامههای قدرتمند و انعطاف پذیر با اکسل ایجاد کنید.
- فرصت های شغلی جدید کسب کنید.
کتابهای معرفی شده ، راهنمای گام به گام جامع و عملی برای افرادی است که (مانند شما) میخواهند به این اهداف برسند.
